硬件部分的连接

#include <SD.h>
#include <HX711_ADC.h>
#include <SPI.h>

File file;

#define BUFFER_SIZE 100
char buffer[BUFFER_SIZE];
/*
创建数据缓冲区，经验证100左右的数据
大小是刚好的，请不要随意修改，因为芯
片内存不够，过大的缓冲区会占用内部资源
在实测中发现单片机会无限制的重启
*/

const int HX711_dout = 5;  //接HX711 dout
const int HX711_sck = 4;   //接 HX711 sck
int Reset_button = 3;      //设置复位按键
int Buzzer = 8;            //设置蜂鸣器输出
/*此处可以根据硬件需求来进行修改*/

HX711_ADC LoadCell(HX711_dout, HX711_sck);
const int calVal_calVal_eepromAdress = 0;

float i;  //存储推力数据的变量


/*校准值*/
//////////////////////////////////////////
float calibrationValue = 7971.5;  //155.8
/////////////////////////////////////////
/*
此处的校准值默认是40Kg（单位是N）量程的传感器
调节的时候遵循“偏大调大，偏小调小”的原则
具体意思是：当校准值的数据比实际的物体
重量偏大 ，将校准值调大 ，当校准值的数据比
实际物体的重量偏小时，将校准值调小
*/


/*数据写入标志*/
/////////////////////////////////////////
float Lnitial_value = 0.5;
/////////////////////////////////////////
/*
当推力大于该数值数据将写入SD卡
*/


int bufferIndex = 0;
unsigned long startTime = 0;  // 秒表开始时间（毫秒）
float elapsedTime = 0.0;      // 经过的时间（秒）

bool startStop = false;  //定义bool变量用于作为计时器启动标志
int period = 1000;
unsigned long timenow = 1000;
unsigned long time2 = 0;

void timting()  //计时器
{
  if (!startStop) {
    startTime = millis();  // 记录秒表开始时间
  }

  if (startStop) {
    elapsedTime = (millis() - startTime) / 1000.0;  // 更新经过的时间（秒）
  }
}

void zeroing()  //复位传感器
{
  tone(Buzzer,2300,500);
  startStop = false;
  file = SD.open("/data.csv", FILE_WRITE);
  if (file) {
    file.println("            ");
    file.println("            ");
    file.println("            ");
    file.println("            ");
    file.close();
  }  //存储空格与新数据进行区分
  LoadCell.tareNoDelay();
  Serial.println("置零");
  delay(1000);
}

void writeFile() {  //写入数据
  if (bufferIndex > 0) {
    file = SD.open("data.csv", FILE_WRITE | O_APPEND);
    if (file) {
      file.write(buffer, bufferIndex);
      file.close();
      bufferIndex = 0;  // 重置缓冲区索引
    } else {
      Serial.println("SD卡丢失!");
    }
  }
}

void HX711_begin() {
  Serial.println("准备...");
  LoadCell.begin();
  unsigned long stabilizingtime = 2000;
  boolean _tare = true;
  LoadCell.start(stabilizingtime, _tare);
  if (LoadCell.getTareTimeoutFlag()) {
    Serial.println("超时，请检查微控制器（MCU）与HX711之间的接线和引脚指定是否正确！！！");
  } else {
    LoadCell.setCalFactor(calibrationValue);  // set calibration factor (float)
    Serial.println("启动完成");
  }
  while (!LoadCell.update())
    ;
  Serial.print("校准值：");
  Serial.println(LoadCell.getCalFactor());
  Serial.print("HX711测量转换时间ms：");
  Serial.println(LoadCell.getConversionTime());
  Serial.print("HX711测量采样率Hz：");
  Serial.println(LoadCell.getSPS());
  Serial.print(" HX711测量稳定时间ms：");
  Serial.println(LoadCell.getSettlingTime());
  Serial.println(" 注意，如果在您的草图中使用delay()，稳定时间可能会显著增加！");
  if (LoadCell.getSPS() < 7) {
    Serial.println("警告：采样率低于规格要求，请检查微控制器（MCU）与HX711之间的接线和引脚分配是否正确");
  } else if (LoadCell.getSPS() > 100) {
    Serial.println("！！采样率高于规格，检查MCU>HX711的接线和引脚指定");
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(Reset_button, INPUT_PULLUP);
  HX711_begin();
  if (!SD.begin()) {
    Serial.println("SD初始化失败");
    while (1) {
      tone(Buzzer,2500,500);
      delay(500);
      tone(Buzzer,1800,500);
      delay(500);
    }
  }
  file = SD.open("/data.csv", FILE_WRITE);
  if (file) {
    file.println("            ");
    file.println("            ");
    file.println("            ");
    file.println("            ");
    file.close();
  }
}


void loop() {
  timting();  //调用计时器
  static boolean newDataReady = 0;
  if (LoadCell.update()) newDataReady = true;
  if (newDataReady) {
    i = LoadCell.getData();
  }
  // 将浮点数转换为字符串，并用逗号隔开
  char num1Str[10];
  char num2Str[10];
  dtostrf(i, 6, 3, num1Str);  // 6表示总宽度，3表示小数点后位数
  dtostrf(elapsedTime, 6, 3, num2Str);
  String data = String(num2Str) + "," + String(num1Str) + "\n";
  if (i > Lnitial_value) {
    startStop = true;  //开始计时
    if (bufferIndex + data.length() < BUFFER_SIZE) {
      data.toCharArray(buffer + bufferIndex, data.length() + 1);
      bufferIndex += data.length();
    } else {
      // 缓冲区满了，写入文件
      writeFile();
    }
    Serial.print(num1Str);//打印推力
    Serial.print(" ");
    Serial.println(num2Str);//打印时间
  } else {
    startStop = false;  //停止计时
  }
  if (digitalRead(Reset_button) == 0) {
    zeroing();
  }
}

硬件部分的连接

代码部分的讲解和运用

提高Hx711采集率的方法

200字以内，仅用于支线交流，主线讨论请采用回复功能。

200字以内，仅用于支线交流，主线讨论请采用回复功能。

200字以内，仅用于支线交流，主线讨论请采用回复功能。

200字以内，仅用于支线交流，主线讨论请采用回复功能。

200字以内，仅用于支线交流，主线讨论请采用回复功能。

200字以内，仅用于支线交流，主线讨论请采用回复功能。

200字以内，仅用于支线交流，主线讨论请采用回复功能。

200字以内，仅用于支线交流，主线讨论请采用回复功能。

200字以内，仅用于支线交流，主线讨论请采用回复功能。

200字以内，仅用于支线交流，主线讨论请采用回复功能。

200字以内，仅用于支线交流，主线讨论请采用回复功能。

200字以内，仅用于支线交流，主线讨论请采用回复功能。

请选择违规类型：

空空如也